iac/modules/vigil/configuration.tf

locals {
  services_toml = [
    for service_group, services in var.monitored_services : templatefile("${path.module}/vigil.service.toml.tpl", {
      service_group_id    = service_group
      service_group_label = service_group
      services            = services
    })
  ]
  vigil_toml = templatefile("${path.module}/vigil.toml.tpl", {
    manager_token        = random_password.token["manager"].result
    reporter_token       = random_password.token["worker"].result
    page_title           = var.page_title
    page_url             = var.page_url
    company_name         = var.company_name
    icon_color           = var.icon_color
    icon_url             = var.icon_url
    logo_color           = var.logo_color
    logo_url             = var.logo_url
    website_url          = var.website_url
    support_url          = var.support_url
    custom_html          = var.custom_html
    services             = local.services_toml
    startup_notification = var.notify_on_startup
    telegram_enable      = var.notify_telegram.token == "" ? "# " : "" // Disable telegram if token is not set
    telegram_bot_token   = var.notify_telegram.token
    telegram_chat_id     = var.notify_telegram.channel
  })
  vigil_toml_checksum = md5(local.vigil_toml)
}
resource "local_file" "vigil_toml" {
  filename = "${path.root}/.debug/vigil.toml"
  content  = local.vigil_toml
}