Rounding the Cube

One of the shape primitives you'll use most often in your OpenSCAD creations is the cube. Rounding the edges of cube-like objects impacts both the visual appeal and functional aspects of the final product. The BOSL2 library provides a variety of methods for rounding edges and corners.

There are four different 3d shape primitives that you can use to make cube-like objects:

cuboid() - Creates a cube with chamfering and roundovers.
cube() - An extended version of OpenSCAD's cube() with anchors for attaching children. (See the Attachments Tutorial).
prismoid() - Creates a rectangular prismoid shape with optional roundovers and chamfering.
rounded_prism() - Makes a rounded 3d object by connecting two polygons with the same vertex count. Rounded_prism supports continuous curvature rounding. (See Types of Roundovers).

BOSL2 provides two different methods for rounding the edges of the cube-like primitives above.

Built-in Rounding - Cuboid, prismoid, and rounded_prism all have built-in arguments for rounding some or all of their edges.
Masking - BOSL2 includes a number of options for masking the edges and corners of objects.

Cuboid Rounding

You can round the edges of a cuboid() with the rounding= argument by specifying the radius of curvature:

include <BOSL2/std.scad>
cuboid([100,80,60], rounding=20);

If you want to round selected edges you can specify which edges using combinations of the named directions LEFT, RIGHT, TOP, BOT, FWD, BACK. See specifying edges for more details.

You can round just the top edges:

include <BOSL2/std.scad>
cuboid([100,80,60], rounding=20, edges = TOP);

...or just the bottom edges. Here we're using the teardrop parameter to limit the overhang angle to enable 3d printing without supports:

include <BOSL2/std.scad>
cuboid([100,80,60], rounding=20, teardrop = 45, edges = BOTTOM);

We can round only the edges aligned with one of the axes, X, Y, or Z:

include <BOSL2/std.scad>
cuboid([100,80,60], rounding=20, edges = "Z");

It is possible to round one or more of the edges while leaving others unrounded:

include <BOSL2/std.scad>
cuboid([100,80,60], rounding=20, edges = TOP+FRONT);

...or exclude the rounding of one or more edges while rounding all the others:

include <BOSL2/std.scad>
cuboid([100,80,60], rounding=20, except = TOP+FRONT);

There is support for filleting edges using negative rounding values:

include <BOSL2/std.scad>
cuboid([100,80,60], rounding=-20, edges = BOTTOM);

Chamfering the edges of the cuboid() can be done in a similar fashion:

include <BOSL2/std.scad>
cuboid([100,80,60], chamfer=20);

You can specify edges as with the cuboid():

include <BOSL2/std.scad>
cuboid([100,80,60], chamfer=20, edges = "Z");

##Prismoid Rounding

The prismoid() differs from the cuboid and cube in that you can only round or chamfer the vertical(ish) edges using the built-in parameters. For those edges, you can specify rounding and/or chamferring for top and bottom separately:

include <BOSL2/std.scad>
prismoid(size1=[35,50], size2=[20,30], h=20, rounding1 = 8, rounding2 = 1);

You can also specify rounding of the vertical(ish) edges on an edge by edge basis by listing the edges in counter-clockwise order starting with the BACK+RIGHT (X+Y+) edge:

include <BOSL2/std.scad>
prismoid(100, 80, rounding1=[0,50,0,50], rounding2=[40,0,40,0], h=50);

##Masking Edges of the Cuboid, Cube and Prismoid ###2D Edge Masking with edge_profile()

One limitation of using rounding arguments in cuboid() is that all the rounded edges must have the same rounding radius. Using masking we have the flexibility to apply different edge treatments to the same cube. Masking can also be used on the cube() and prismoid() shapes.

2D edge masks are attached to edges using edge_profile(). They have a default tag of "remove" to enable differencing them away from your cube using diff().

We can use a negative rounding value to fillet the bottom of a cuboid and edge_profile() to round the top. Here edge_profile() applies a 2d roundover mask to the top edges of the cuboid.

include <BOSL2/std.scad>
diff()
    cuboid([50,60,70], rounding = -10, edges = BOT)
        edge_profile(TOP)
            mask2d_roundover(r=10);

See mask2d_roundover() for additional mask parameters. Here we use the inset parameter in mask2d_roundover:

include <BOSL2/std.scad>
diff()
	cube([50,60,70],center=true)
   		edge_profile(TOP, except=[BACK,TOP+LEFT])
       	mask2d_roundover(h=12, inset=4);

In addition to the simple roundover mask, there are masks for cove, chamfer, rabbet, dovetail, teardrop and ogee edges.

The mask2d_ogee() only works on cube() and cuboid() shapes, or a prismoid() where size2 >= size1 in both the X and Y dimensions.

include <BOSL2/std.scad>
diff()
	prismoid(size1 = [50,50],size2 = [80,80], rounding1 = 25, height = 80)
		edge_profile(TOP)
			mask2d_ogee([
            "xstep",8,  "ystep",5,  // Starting shoulder.
            "fillet",5, "round",5,  // S-curve.
            "ystep",3,  "xstep",3   // Ending shoulder.
        ]);

You can use edge-profile() to round the top or bottom of a prismoid(). Because the side faces of a prismoid() are not strictly vertical, it's is necessary to increase the length of the masks using the excess parameter in edge_profile().

include<BOSL2/std.scad>
diff()
	prismoid(size1=[35,50], size2=[30,30], h=20, rounding1 = 8, rounding2 = 0)
   		edge_profile([TOP+LEFT, TOP+RIGHT], excess = 5)
       	mask2d_roundover(r = 15, mask_angle = $edge_angle);

###3D Edge and Corner Masking

BOSL2 contains a number of 3d edge and corner masks in addition to the 2d edge profiles shown above.

The 3d edge masks have the advantage of being able to vary the rounding radius along the edge. 3d edge masks can be attached using edge_mask(). They have a default tag of "remove" to enable differencing them away from your cube using diff().

include <BOSL2/std.scad>
diff()
	cuboid(80)
		edge_mask(TOP+FWD)
			rounding_edge_mask(r1 = 40, r2 = 0, l = 80);

8.1 KiB Raw Blame History

Rounding the Cube

Cuboid Rounding

8.1 KiB

Raw Blame History